1 files changed, 45 insertions, 92 deletions
diff --git a/src/irmd/CMakeLists.txt b/src/irmd/CMakeLists.txt
index 32904d59..9aa747ca 100644
--- a/src/irmd/CMakeLists.txt
+++ b/src/irmd/CMakeLists.txt
@@ -1,114 +1,67 @@
-include_directories(${CMAKE_CURRENT_SOURCE_DIR})
-include_directories(${CMAKE_CURRENT_BINARY_DIR})
+# IRMd (IPC Resource Manager daemon) build configuration
+# Configuration options are in cmake/config/global.cmake and cmake/config/irmd.cmake
 
-include_directories(${CMAKE_SOURCE_DIR}/include)
-include_directories(${CMAKE_BINARY_DIR}/include)
-
-set(OUROBOROS_CONFIG_DIR /etc/ouroboros CACHE STRING
-  "Configuration directory")
-
-find_library(LIBTOML_LIBRARIES toml QUIET)
-if (LIBTOML_LIBRARIES)
-  set(DISABLE_CONFIGFILE FALSE CACHE BOOL
-    "Disable configuration file support")
-  if (NOT DISABLE_CONFIGFILE)
-    set(OUROBOROS_CONFIG_FILE irmd.conf CACHE STRING
-      "Name of the IRMd configuration file")
-    set(HAVE_TOML TRUE)
-    message(STATUS "Found TOML C99 library: " ${LIBTOML_LIBRARIES})
-    message(STATUS "Configuration file support enabled")
-    message(STATUS "Configuration directory: ${OUROBOROS_CONFIG_DIR}")
-    set(INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_BINDIR}")
-    configure_file("${CMAKE_SOURCE_DIR}/irmd.conf.in"
-      "${CMAKE_BINARY_DIR}/irmd.conf.example" @ONLY)
-    install(FILES "${CMAKE_BINARY_DIR}/irmd.conf.example"
-      DESTINATION "${OUROBOROS_CONFIG_DIR}")
-    unset(INSTALL_DIR)
-    find_path(LIBTOML_INCLUDE toml.h)
-    mark_as_advanced(LIBTOML_LIBRARIES LIBTOML_INCLUDE)
-  else ()
-    message(STATUS "Configuration file support disabled by user")
-    unset(OUROBOROS_CONFIG_FILE CACHE)
-    set(HAVE_TOML FALSE)
-  endif ()
-else ()
-  message(STATUS "Install tomlc99 for config file support")
-  message(STATUS "     https://github.com/cktan/tomlc99")
-  set(LIBTOML_LIBRARIES "")
-  unset(DISABLE_CONFIGFILE CACHE)
-  unset(HAVE_TOML)
-endif ()
-
-set(OUROBOROS_SECURITY_DIR "${OUROBOROS_CONFIG_DIR}/security" CACHE STRING
-  "Security directory holding authentication information")
-set(OUROBOROS_CA_CRT_DIR "${OUROBOROS_SECURITY_DIR}/cacert" CACHE STRING
-  "Directory holding trusted CA certificates")
-set(OUROBOROS_SRV_CRT_DIR "${OUROBOROS_SECURITY_DIR}/server" CACHE STRING
-  "Directory holding trusted CA certificates")
-set(OUROBOROS_CLI_CRT_DIR "${OUROBOROS_SECURITY_DIR}/client" CACHE STRING
-  "Directory holding trusted CA certificates")
-set(OUROBOROS_UNTRUSTED_DIR "${OUROBOROS_SECURITY_DIR}/untrusted" CACHE STRING
-  "Directory holding untrusted intermediate certificates")
-
-set(IRMD_REQ_ARR_TIMEOUT 1000 CACHE STRING
-  "Timeout for an application to respond to a new flow (ms)")
-set(BOOTSTRAP_TIMEOUT 5000 CACHE STRING
-  "Timeout for an IPCP to bootstrap (ms)")
-set(ENROLL_TIMEOUT 20000 CACHE STRING
-  "Timeout for an IPCP to enroll (ms)")
-set(REG_TIMEOUT 20000 CACHE STRING
-  "Timeout for registering a name (ms)")
-set(QUERY_TIMEOUT 200 CACHE STRING
-  "Timeout to query a name with an IPCP (ms)")
-set(CONNECT_TIMEOUT 20000 CACHE STRING
-  "Timeout to connect an IPCP to another IPCP (ms)")
-set(FLOW_ALLOC_TIMEOUT 20000 CACHE STRING
-  "Timeout for a flow allocation response (ms)")
-set(IRMD_MIN_THREADS 8 CACHE STRING
-  "Minimum number of worker threads in the IRMd")
-set(IRMD_ADD_THREADS 8 CACHE STRING
-  "Number of extra threads to start when the IRMD faces thread starvation")
-set(IRMD_PKILL_TIMEOUT 30 CACHE STRING
-  "Number of seconds to wait before sending SIGKILL to subprocesses on exit")
-set(IRMD_KILL_ALL_PROCESSES TRUE CACHE BOOL
-  "Kill all processes on exit")
-set(DEBUG_PROTO_OAP FALSE CACHE BOOL
-  "Add Flow allocation protocol message output to IRMd debug logging")
+# Generate and install configuration files if TOML support available
+# HAVE_TOML is set in cmake/dependencies/irmd/libtoml.cmake
+if(HAVE_TOML)
+  set(INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/${CMAKE_INSTALL_BINDIR}")
+  configure_file("${CMAKE_SOURCE_DIR}/irmd.conf.in"
+    "${CMAKE_BINARY_DIR}/${OUROBOROS_CONFIG_FILE}.example" @ONLY)
+  configure_file("${CMAKE_SOURCE_DIR}/enc.conf.in"
+    "${CMAKE_BINARY_DIR}/enc.conf.example" @ONLY)
+  install(FILES "${CMAKE_BINARY_DIR}/${OUROBOROS_CONFIG_FILE}.example"
+    DESTINATION "${OUROBOROS_CONFIG_DIR}")
+  install(FILES "${CMAKE_BINARY_DIR}/enc.conf.example"
+    DESTINATION "${OUROBOROS_CONFIG_DIR}")
+  install(CODE "
+    if(NOT EXISTS \"${OUROBOROS_CONFIG_DIR}/${OUROBOROS_CONFIG_FILE}\")
+      file(WRITE \"${OUROBOROS_CONFIG_DIR}/${OUROBOROS_CONFIG_FILE}\" \"\")
+    endif()
+  ")
+  unset(INSTALL_DIR)
+endif()
 
 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/config.h.in"
   "${CMAKE_CURRENT_BINARY_DIR}/config.h" @ONLY)
 
-set(SOURCE_FILES
-  # Add source files here
+set(IRMD_SOURCES
   ipcp.c
   configfile.c
   main.c
-  oap.c
+  oap/io.c
+  oap/hdr.c
+  oap/auth.c
+  oap/srv.c
+  oap/cli.c
   reg/flow.c
   reg/ipcp.c
+  reg/pool.c
   reg/proc.c
   reg/prog.c
   reg/name.c
   reg/reg.c
-  )
+)
+
+add_executable(irmd ${IRMD_SOURCES})
 
-add_executable (irmd ${SOURCE_FILES})
+add_dependencies(irmd version_header)
 
-target_link_libraries (irmd LINK_PUBLIC ouroboros-common
-  ${LIBTOML_LIBRARIES})
+target_include_directories(irmd PRIVATE
+  ${CMAKE_CURRENT_SOURCE_DIR}
+  ${CMAKE_CURRENT_BINARY_DIR}
+  ${CMAKE_SOURCE_DIR}/include
+  ${CMAKE_BINARY_DIR}/include)
 
-if (HAVE_TOML)
-  target_include_directories(irmd PUBLIC ${LIBTOML_INCLUDE})
-endif ()
+target_link_libraries(irmd PRIVATE ouroboros-common)
+if(HAVE_TOML)
+  target_link_libraries(irmd PRIVATE toml::toml)
+endif()
 
-include(AddCompileFlags)
-if (CMAKE_BUILD_TYPE MATCHES "Debug*")
-  add_compile_flags(irmd -DCONFIG_OUROBOROS_DEBUG)
-endif ()
+ouroboros_target_debug_definitions(irmd)
 
 install(TARGETS irmd RUNTIME DESTINATION ${CMAKE_INSTALL_SBINDIR})
 
-add_subdirectory(reg)
 if(BUILD_TESTS)
-  add_subdirectory(tests)
-endif ()
+  add_subdirectory(oap/tests)
+  add_subdirectory(reg/tests)
+endif()